C **********************************************************************
C  AIM IS TO SOLVE THE PARABOLIC HEAT CONDUCTION EQUATION (OR DIFFUSION-EQ.)
C  PT/PT = (L/ROH C) * (P^2 T / P X^2)
C  WERE L IS THE HEAT CONDUCTION IN W/(K M)
C  ROH IS THE DENSITY IN KG/M³
C  AND C IS THE VOLUMETRIC HEAT CAPACITY IN J/(KG K)
C  FORMULATED AS IMPLICITE FINITE DIFFERENCES EQUATION
C  [(T(T+1,I)-T(T,I))/DELTA T]-[(L/ROH C)*((T(T+1,I-1)-2*T(T,I-1)+T(T+1,I-1))/(DELTA X)**2)]=0
C  SOLVED FOR T(T,I):
C  WITH H = ((L * DELTA T)/(2*DELTA X))
C  -H*T(T+1,I-1)+(1+2H)T(T+1,I)-H*T(T+1,I+1) = T(T,I)
C  SORTED AFTER I IN MATRIX-WRITING (AT THE LEFT ALL VALUES AT T+1):
C  THE LEFT SIDE IS UNKNOWN THE RIGHT IS KNOWN:
C  _                                      _  _     _        _      _
C |  1+2H -H    0   0   0   0   0   0 ... | | T(1) |       | T(t,1) |
C |   -H  1+2H -H   0   0   0   0   0 ... | | T(2) |       |        |
C |    0  -H  1+2H -H   0   0   0   0 ... | | T(3) |       |        |
C |    0   0   -H 1+2H -H   0   0   0 ... | | T(4) |       |        |
C |               .     .    .            | |  .   |  =    |        |
C |                   .     .     .       | |  .   |       |        |
C |                  .     .     .        | |  .   |       |        |
C |                        .     .        | |  .   |       |        |
C |_                        0  -H 1+2H -H_| |_T(N)_|       |_T(t,N)_|
C
C  THIS KANN BE WRITTEN AS :
C     A * X = B
C TO SOLVE THIS LINEAR EQUATION THE Anderson Subroutine sy IS USED 
C (SEE END OF THIS FILE)
C **********************************************************************
      PROGRAM IMPLHF2
      
      IMPLICIT NONE
      
      INTEGER           J,JMAX,JMAXS,TMAX,TSTEP,TNEU,AUSG,divt
      PARAMETER(        JMAXS=200)
      DOUBLE PRECISION  LAMBDA,DELTAT,DELTAX,ROHC
      DOUBLE PRECISION  H,BC,RZ,Q,INITEMP
      DOUBLE PRECISION  AA(JMAXS),BB(JMAXS),CC(JMAXS),DD(JMAXS)
C **********************************************************************
C     READ PARAMETER
      OPEN(49,FILE='parameter.dat')
1     READ(49,*) LAMBDA
2     READ(49,*) ROHC
3     READ(49,*) Q
4     READ(49,*) RZ
5     READ(49,*) TMAX
6     READ(49,*) DELTAT
7     READ(49,*) INITEMP
8     READ(49,*) DELTAX
9     READ(49,*) JMAX
10    READ(49,*) AUSG
11    READ(49,*) BC
      
      OPEN(50,FILE='IMPL.OUT') 
C ************************* START/INITIAL CONDITION ********************
      DO J=1, JMAX
C     CENTRAL DIFFERENCES  OF SECOND ORDER
      H = ((LAMBDA * DELTAT)/(ROHC*DELTAX*DELTAX))
C.. BB = COEFFICIENT BEHIND DIAGONAL (UNDER)
C.. DD = COEFFICIENT ON DIAGONAL 
C.. AA = COEFFICIENT AHEAD OF DIAGONAL (ABOVE)
C.. CC = ELEMENT OF CONSTANT VECTOR --> TEMPERATURE
      DD(J) = (1.D0+2.D0*H)
      AA(J) = -1.D0*H
      BB(J) = -1.D0*H
      CC(J) = INITEMP
      ENDDO
      WRITE(*,*) 'H = ', H      
      AUSG = 20
      divt = int(TMAX/AUSG)
      TSTEP = int(DELTAT) 
C **********************************************************************      
C     BEGIN TIME LOOP
      DO TNEU=0, TMAX, TSTEP
C **********************************************************************      
C     BORDER CONDITIONS
C AT THE FIRST GRID NODES A DIRICHLET BC (CNSTANT TEMPERATURE)
      CC(1)      = 283.15D0+50.D0
      CC(2)      = 283.15D0+50.D0      
      CC(3)      = 283.15D0+50.D0
C AT THE LAST GRID NODES A NEUMANN BC (CONSTANT FLOW)
      CC(JMAX-1) = CC(JMAX-2)
      CC(JMAX)   = CC(JMAX-1)
C **********************************************************************
      IF(MOD(real(TNEU-TSTEP),real(divt)).EQ.0.OR.TNEU.EQ.TMAX)THEN
      WRITE(*,*) 'TEST9: ', TNEU, (MOD(TNEU,divt))
      DO J=1,JMAX
      WRITE(50,'(I8,1X,F20.8)') J,CC(J)
      ENDDO
      ENDIF
C **********************************************************************      
C     SOLVER - SUBROUTINE OF ANDERSON
      CALL SY(1,JMAX,BB,DD,AA,CC)
C **********************************************************************      
C     END OF TIMELOOP
      ENDDO
      WRITE(*,*) H
      END
      
C **********************************************************************      
C     ANDERSON, D.A. 1984: Computational Fluid Mechanics and 
C     Heat Transfer. 550 APPENDIX A
C     Subroutine SY solves a tridiagonal system of equations following 
C     the THOMAS algorithm.
C           A * x = b 
C
C   LISTING OF SUBROUTINE SY
C
C **********************************************************************      
      SUBROUTINE SY(IL,IU,BB,DD,AA,CC)

      IMPLICIT NONE
      
      INTEGER           LP,IL,IU,I,J
      DOUBLE PRECISION  AA(IU),BB(IU),CC(IU),DD(IU),DD2(IU)
      DOUBLE PRECISION  R

C
C.. SUBROUTINE SY SOLVES TRIDIAGONAL SYSTEM BY ELIMINATION
C.. IL = SUBSCRIPT OF FIRST EQUATION
C.. IU = SUBSCRIPT OF LAST EQUATION
C.. BB = COEFFICIENT BEHIND DIAGONAL (UNTEN)
C.. DD = COEFFICIENT ON DIAGONAL 
C.. AA = COEFFICIENT AHEAD OF DIAGONAL (OBEN)
C.. CC = ELEMENT OF CONSTANT VECTOR
C.. ESTABLISH UPPER TRIANGULAR MATRIX
C

      DD2(IL) = DD(IL)
      
      R = 0.D0
      LP = IL+1
      DO 10 I = LP,IU
      R = (BB(I)/DD2(I-1))
      DD2(I) = DD(I)-R*AA(I-1)
      CC(I) = CC(I)-R*CC(I-1)
   10 CONTINUE
C
C..BACK SUBSTITUTION
C
      CC(IU) = CC(IU)/DD2(IU)
      DO 20 I = LP,IU
      J = IU-I+IL
      CC(J) = (CC(J)-AA(J)*CC(J+1))/DD2(J)
   20 CONTINUE
C
C..SOLUTION STORED IN CC
C
      RETURN
      END
